Помогите с фонариком

Тема в разделе "Counter-Strike: Global Offensive", создана пользователем Agony, 6 май 2016.

  1. Agony

    Agony

    Сообщения:
    128
    Симпатии:
    18
    Скачал плагин с фонариком , он работает всё без проблем но на f больше оружие не показывается , можно сделать как то чтобы , на f фонарик работал и оружие показывалось чтобы они сочитались .
    Вот .sp

    Код:
    #pragma semicolon 1
    #include <sdktools>
    #define PVERSION "1.3.62"
    
    new Handle:gH_Enabled = INVALID_HANDLE;
    new Handle:gH_LAW = INVALID_HANDLE;
    new Handle:gH_Return = INVALID_HANDLE;
    new Handle:gH_Sound = INVALID_HANDLE;
    new Handle:gH_SoundAll = INVALID_HANDLE;
    
    new bool:bEnabled = true;
    new bool:bLAW = true;
    new bool:bRtn = false;
    new bool:bSnd = false;
    new bool:bSndAll = true;
    
    new String:zsSnd[255];
    
    public Plugin:myinfo =
    {
        name = "Flashlight",
        author = "Mitch",
        description = "Replaces +lookatweapon with a toggleable flashlight. Also adds the command: sm_flashlight",
        version = PVERSION,
        url = "https://forums.alliedmods.net/showthread.php?t=227224"
    };
    
    public OnPluginStart()
    {
        gH_Enabled = CreateConVar("sm_flashlight_enabled", "1",
                        "0 = Disables flashlight; 1 = Enables flashlight",         FCVAR_PLUGIN, true, 0.0, true, 1.0);
        gH_LAW = CreateConVar("sm_flashlight_lookatweapon", "1",
                        "0 = Doesn't use +lookatweapon; 1 = hooks +lookatweapon",         FCVAR_PLUGIN, true, 0.0, true, 1.0);
        gH_Return = CreateConVar("sm_flashlight_return", "0",
                        "0 = Doesn't return blocking +look at weapon; 1 = Does return", FCVAR_PLUGIN, true, 0.0, true, 1.0);
        gH_Sound = CreateConVar("sm_flashlight_sound", "items/flashlight1.wav",
                        "Sound path to use when a player uses the flash light.", FCVAR_PLUGIN);
        gH_SoundAll = CreateConVar("sm_flashlight_sound_all", "1",
                        "Play the sound to all players, or just to the activator?", FCVAR_PLUGIN);
        UpdateSound();
        HookConVarChange(gH_Sound, ConVarChanged);
        HookConVarChange(gH_Enabled, ConVarChanged);
        HookConVarChange(gH_LAW, ConVarChanged);
        HookConVarChange(gH_Return, ConVarChanged);
        AutoExecConfig();
    
        CreateConVar("sm_flashlight_version", PVERSION, "CsGoFlashlight Version", FCVAR_DONTRECORD|FCVAR_NOTIFY);
    
        AddCommandListener(Command_LAW, "+lookatweapon");    //Hooks cs:go's flashlight replacement 'look at weapon'.
        RegConsoleCmd("sm_flashlight", Command_FlashLight);     //Bindable Flashlight command
    }
    
    public ConVarChanged(Handle:cvar, const String:oldVal[], const String:newVal[])
    {
        if(cvar == gH_Enabled)
            bEnabled = bool:StringToInt(newVal);
        if(cvar == gH_LAW)
            bLAW = bool:StringToInt(newVal);
        if(cvar == gH_Return)
            bRtn = bool:StringToInt(newVal);
        if(cvar == gH_SoundAll)
            bSndAll = bool:StringToInt(newVal);
        if(cvar == gH_Sound) {
            UpdateSound();
        }
    }
    
    public UpdateSound() {
        decl String:formatedSound[256];
        GetConVarString(gH_Sound, formatedSound, sizeof(formatedSound));
        if(StrEqual(formatedSound, "") || StrEqual(formatedSound, "0")) {
            bSnd = false;
        } else {
            strcopy(zsSnd, sizeof(zsSnd), formatedSound);
            bSnd = true;
            PrecacheSound(zsSnd);
            if(!StrEqual(formatedSound, "items/flashlight1.wav")) {
                Format(formatedSound, sizeof(formatedSound), "sound/%s", formatedSound);
                AddFileToDownloadsTable(formatedSound);
            }
        }
    }
    
    public OnMapStart() {
        if(bSnd) {
            PrecacheSound(zsSnd, true);
        }
    }
    
    public Action:Command_LAW(client, const String:command[], argc)
    {
        if(!bLAW || !bEnabled) //Enable this hook?
            return Plugin_Continue;
    
        if(!IsClientInGame(client)) //If player is not in-game then ignore!
            return Plugin_Continue;
    
        if(!IsPlayerAlive(client)) //If player is not alive then continue the command.
            return Plugin_Continue; 
    
        ToggleFlashlight(client);
    
        return (bRtn) ? Plugin_Continue : Plugin_Handled;
    }
    
    public Action:Command_FlashLight(client, args)
    {
        if(!bEnabled)
            return Plugin_Handled;
    
        if (IsClientInGame(client) && IsPlayerAlive(client)) {
            ToggleFlashlight(client);
        }
        return Plugin_Handled;
    }
    
    ToggleFlashlight(client) {
        SetEntProp(client, Prop_Send, "m_fEffects", GetEntProp(client, Prop_Send, "m_fEffects") ^ 4);
        if(bSnd) {
            if(bSndAll) {
                EmitSoundToAll(zsSnd, client);
            } else {
                EmitSoundToClient(client, zsSnd);
            }
        }
    }
    Кому нужен сам плагин с фонариком вот :
     

    Вложения:

  2. Tonki_Ton

    Tonki_Ton

    Сообщения:
    317
    Симпатии:
    31
    В плагине есть квар что бы "на f фонарик работал и оружие показывалось чтобы они сочитались"
     
  3. Agony

    Agony

    Сообщения:
    128
    Симпатии:
    18
    Не понял , какой именно квар можно по подробнее?
     
  4. EmojiQ

    EmojiQ Простой человек

    Сообщения:
    169
    Симпатии:
    16
    impulse 100 попробуй.
     
  5. Yura7181

    Yura7181

    Сообщения:
    369
    Симпатии:
    295
    Попробуй это. У меня работает так: нажимаю на F (рус. буква А) фонарь светит и оружие осматриваешь.

    На всякий случай рестартани сервер.
     

    Вложения:

    Святослав124 нравится это.
  6. Agony

    Agony

    Сообщения:
    128
    Симпатии:
    18
    • Оскорбление других участников
    Вы такие ДЦПшники накручиваете посты , я задал вопрос именно о ПЛАГИНЕ БЛ**** . Спасибо Yura7181
     
  7. Mr.Credo

    Mr.Credo

    Сообщения:
    138
    Симпатии:
    4
    @Yura7181, этот же плагин можешь сделать только на другую кнопку вместо F na T
     
  8. Yura7181

    Yura7181

    Сообщения:
    369
    Симпатии:
    295
    Святослав124 нравится это.
  9. Mr.Credo

    Mr.Credo

    Сообщения:
    138
    Симпатии:
    4
    @Yura7181, чет не могу разобраться толком
     
  10. Yura7181

    Yura7181

    Сообщения:
    369
    Симпатии:
    295
    Написано бинд поставить можно на любую клавишу.

    Например: bind t sm_flashlight
     
    Святослав124 нравится это.
  11. Kruzi

    Kruzi

    Сообщения:
    160
    Симпатии:
    2
    Поставь значения конфиге плагина
    csgo/cfg/soursemod/plugin.flashlight.cfg
    Код:
    sm_flashlight_lookatweapon 1
    sm_flashlight_return 1